Model/deployment/terraform/lambda/modelling_e2e/main.tf

data "terraform_remote_state" "shared" {
  backend = "s3"
  config = {
    bucket = "assessment-model-terraform-state"
    key    = "env:/${var.stage}/terraform.tfstate"
    region = "eu-west-2"
  }
}

data "aws_secretsmanager_secret_version" "db_credentials" {
  secret_id = "${var.stage}/assessment_model/db_credentials"
}

locals {
  db_credentials = jsondecode(data.aws_secretsmanager_secret_version.db_credentials.secret_string)
}

module "lambda" {
  source = "../../modules/lambda_with_sqs"

  name  = var.lambda_name
  stage = var.stage

  image_uri = local.image_uri

  reserved_concurrent_executions = var.reserved_concurrent_executions

  batch_size          = var.batch_size
  maximum_concurrency = var.maximum_concurrency

  timeout     = 900
  memory_size = 3008

  environment = {
    STAGE                = var.stage
    LOG_LEVEL            = "info"
    POSTGRES_USERNAME    = local.db_credentials.db_assessment_model_username
    POSTGRES_PASSWORD    = local.db_credentials.db_assessment_model_password
    POSTGRES_HOST        = var.db_host
    POSTGRES_DATABASE    = var.db_name
    POSTGRES_PORT        = var.db_port
    OPEN_EPC_API_TOKEN   = var.open_epc_api_token
    GOOGLE_SOLAR_API_KEY = var.google_solar_api_key
    DATA_BUCKET          = "retrofit-data-${var.stage}"
  }
}

resource "aws_iam_role_policy_attachment" "modelling_e2e_s3_read" {
  role       = module.lambda.role_name
  policy_arn = data.terraform_remote_state.shared.outputs.modelling_e2e_s3_read_arn
}